NavList:
A Community Devoted to the Preservation and Practice of Celestial Navigation and Other Methods of Traditional Wayfinding
From: Peter Hakel
Date: 2010 Dec 23, 09:31 -0800
I wouldn't regard the use of electronics as "cheating." NavList member John Karl has a nice chapter on this subject called "Tables, Calculators, and Computers: The Debate" in his book. If maximum electronic portability is desired (both in regard to platform independence and the physical size of the gadget) you can do these types of calculations rather easily on a smartphone, please see:
http://www.navigation-spreadsheets.com/lops.html#many_body_fix
Note that this solution also accounts for the motion of the vessel. The change in declination is not included but that is probably because, judging from the example given in the NA, this method is primarily intended for twilight observations of stars.
Peter Hakel
From: Andrew Nikitin <nsg21@hotmail.com>
To: NavList@fer3.com
Sent: Thu, December 23, 2010 6:50:18 AM
Subject: [NavList] Re: Finding The Symmedian
Regarding finding most probable position.
The equations involved are so simple that could be solved on a
calculator. Admittedly, use of calculator is "cheating", but
much less so than a laptop. I would also guess that calculator
does not take nearly as much space on a charting table as
laptop.
Also, when finding MPP digitaly, any number of LOPs can be
used, not just 3.
Here is a reminder on how to do it.
If all LOPs are represented as azimuth and offset vectors
relative to same origin (such as AP), the corresponding
equations can be written out without even plotting them
first. For example, for LOP with given AZ and D the equation
would be x*sin(AZ)+y*cos(AZ)=D
Each sight contributes one equation. For 3 sights we have an
overdefined system of 3 equations with 2 variables (x y). These
equations can be solved using least square method (which exactly
minimizes sum of square distances
from point (x,y) to each of
the lines). Substituting our equation coefficients into formula
and making long things short we get the following solution:
A=sum(sin(AZi)^2)
B=sum(sin(AZi)*cos(AZi))
C=sum(cos(AZi)^2)
D=sum(sin(AZi)*Di)
E=sum(cos(AZi)*Di)
DET=A*C-B*B
x=(D*C-E*B)/DET
y=(E*C-D*B)/DET
(Here AZi,Di are azimuth vectors and offsets of LOPs, and
resulting x and y is an offset vector relative to same origin as
LOPs)
Solving it by punching keys is tedious, but this is what
programmable calculators are for. The direct implementation of
the above formulas should not be too difficult.
Here is, for example, what I wrote for HP35s. It is not
especially complicated program and it wasn't hard to write.
Program for other calculators will be very similar in
complexity.
(XEQ L002 initializes routine, than user enters AZi <ENTER> Di
<R/S> And when all pairs are
entered, XEQ L003 calculates dx and
dy)
L001 LBL L
L002 GTO L004
L003 GTO L034
L004 0
L005 STO A
L006 STO B
L007 STO D
L008 STO E
L009 STO C
L010 R/S
L011 STO F
L012 X<>Y
L013 STO H
L014 COS
L015 STO G
L016 *
L017 STO+ E
L018 RCL H
L019 SIN
L020 STO H
L021 RCL* F
L022 STO+ D
L023 RCL H
L024 X^2
L025 STO+ A
L026 RCL H
L027 RCL* G
L028 STO+ B
L029 1
L030 STO+ C
L031 RCL C
L032 R/S
L033 GTO L011
L034 RCL C
L035 RCL- A
L036 STO H
L037 RCL* A
L038 RCL B
L039 X^2
L040 -
L041 1/x
L042 STO G
L043 RCL H
L044 RCL* D
L045 RCL E
L046 RCL* B
L047 -
L048 *
L049 RCL H
L050 RCL* E
L051 RCL D
L052 RCL* B
L053 -
L054 RCL* G
L055 RTN
----------------------------------------------------------------
NavList message boards and member settings: www.fer3.com/NavList
Members may optionally receive posts by email.
To cancel email delivery, send a message to NoMail[at]fer3.com
----------------------------------------------------------------
